# languages/golang/import-path -- lintian check script -*- perl -*-
#
# Copyright (C) 2004 Marc Brockschmidt
# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
# Copyright (C) 2020-2021 Felix Lechner
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, you can find it on the World Wide
# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
# MA 02110-1301, USA.

package Lintian::Check::Languages::Golang::ImportPath;

use v5.20;
use warnings;
use utf8;
use Unicode::UTF8 qw(encode_utf8);
use Const::Fast;

const my $EMPTY => q{};

use Moo;
use namespace::clean;

with 'Lintian::Check';

sub source {
    my ($self) = @_;

    return
      unless $self->processable->relation('Build-Depends')
      ->satisfies('golang-go | golang-any');

    my $control = $self->processable->debian_control;
    my $source_fields = $control->source_fields;

    if (!$source_fields->declares('XS-Go-Import-Path')) {
        $self->hint('missing-xs-go-import-path-for-golang-package');
        return;
    }

    my $gomod = $self->processable->patched->resolve_path('go.mod');
    if (defined $gomod && $gomod->is_open_ok) {
        open(my $fd, '<', $gomod->unpacked_path)
          or die encode_utf8('Cannot open ' . $gomod->unpacked_path);

        my $xs_go_import_path
          = (split /,/,$source_fields->value('XS-Go-Import-Path'))[0];
        $xs_go_import_path =~ s/\s+$//g;
        my $go_module_path = $EMPTY;

        while (my $line = <$fd>) {

            if ($line =~ m{^ \s* module \s+ (\S+) }x) {
                $go_module_path = $1;
                last;
            }

        }
        close $fd;

        $self->hint('xs-go-import-path-differs-from-module-path',
            $xs_go_import_path, ' vs ', $go_module_path)
          if $go_module_path ne $xs_go_import_path;
    }

    return;
}

1;

# Local Variables:
# indent-tabs-mode: nil
# cperl-indent-level: 4
# End:
# vim: syntax=perl sw=4 sts=4 sr et
